Poševni met

Z linearnim uporom

eq = {x''[t]== -β x'[t],y''[t]==  -g - β y'[t],x[0]== 0,y[0]== 0,x'[0]==  v0 Cos[α],y'[0]== v0 Sin[α]}

Brezdimenzijski zapis

x[t_] = ξ[β t]
y[t_] = η[β t]

eqeq=Simplify[eq/.{t β -> τ,g-> k1 (β^2),v0-> k2 β}]

slv=Simplify[DSolve[eqeq,{ξ[τ],η[τ]},τ]]

ξξ[τ_] = Simplify[ξ[τ]/.slv[[1]]]
ηη[τ_] = Simplify[η[τ]/.slv[[1]]]

Metni prostor

Izračun ogrinjače

pom1=Simplify[D[ηη[t],t]D[ξξ[t],α] - D[ξξ[t],t]D[ηη[t],α]]

slvt=Solve[pom1==0,t]

xo=Simplify[ξξ[t]/. slvt[[2]]]
yo=FullSimplify[ηη[t]/. slvt[[2]]]

Metna višina

Simplify[yo/.α-> π/2]

example={k1-> 1,k2-> 2}
slika1=ParametricPlot[{xo,yo}/.example,{α,π/8,π/2}]

Primer

Družina tirov za različne kote metanja v metnem prostoru

n= 10;
tableα=Table[((k π)/(2 n)),{k,1,n-1}];
colour = Table[Hue[(k/n)],{k,1,n-1}];
slika2=Table[ParametricPlot[{ξξ[τ],ηη[τ]}/.example/.α->tableα[[k]],{τ,0,3}, PlotStyle-> colour[[k]]],{k,1,n-1}];
slikaLinearniUpor=Show[Join[slika2,{slika1}],PlotRange-> All]
Clear[n]

S kvadratnim uporom

Clear[x,y]
eq = {x''[t]== -β (Sqrt[((x'[t])^2)+((y'[t])^2)]) x'[t],y''[t]==  -g - β (Sqrt[((x'[t])^2)+((y'[t])^2)])y'[t],x[0]== 0,y[0]== 0,x'[0]==  v0 Cos[α],y'[0]== v0 Sin[α]}

Brezdimenzijski zapis

x[t_] = (1/β)ξ[ t]
y[t_] = (1/β)η[ t]

eqeq=Simplify[eq/.{g-> (k1/β),v0-> (k2/β)},β>0]

slv=Simplify[DSolve[eqeq,{ξ[t],η[t]},t]]

Rešitev v zaprti obliki ni znana

Numerična rešitev

example={k1-> 1,k2-> 2}
tmax = 3

Clear[slv]
slv[αα_]:=NDSolve[eqeq/.example/.α->αα,{ξ[t],η[t]},{t,0,tmax}]

n= 10;
tableα=Table[((k π)/(2 n)),{k,1,n-1}];
colour = Table[Hue[(k/n)],{k,1,n-1}];
slika=Table[ParametricPlot[Evaluate[{ξ[t],η[t]}/.slv[tableα[[k]]]],{t,0,tmax}, PlotStyle-> {Dashed,colour[[k]]}],{k,1,n-1}];
slikaKvadratniUpor=Show[slika,PlotRange-> All]
Clear[n]

Primerjava

Show[{slikaKvadratniUpor,slikaLinearniUpor}]