Vrteče se matematično nihalo

Materialna točka se giblje po gladki krožnici, ki se enakomerno vrti okrog osi, ki gre skozi središče krožnice in leži v ravnini krožnice. Na točko deluje sila teže v navpični smeri.

Analitična obravnava

Koordinatni sistem

Os x usmerimo v smer sile teže, os y pa leži v ravnini kroga.

vr = R0{Cos[ϕ[t]],Sin[ϕ[t]],0};
vω = -ω {1,0,0};

V RKS, ki se hkrati vrti s krožnico je rezultanta sil enaka

vf =  m g {1,0,0}+ fr {Cos[ϕ[t]],Sin[ϕ[t]],0} + f3{0,0,1} - m Cross[vω,Cross[vω,vr]] - 2m Cross[vω,D[vr,t]]

Tu je sta fr in f3 komponenti sile vezi.

Newtonova enačba v RKS

va = D[vr,{t,2}]

eq = m va - vf

Ker je krožnica gladka velja izrek o energiji. Energijsko enačbo dobimo, če pomnožimo Newtonovo enačbo skalarno s tangentni vektorjem.

vϕ = D[{Cos[ϕ[t]],Sin[ϕ[t]],0},ϕ[t]]

pom1=Simplify[eq.vϕ]

Pomnmožimo dobljeno z obodno hitrostjo in integrirajmo po času

pom2=R0 Simplify[ Integrate[ϕ'[t]pom1,t]]

Energijska konstanta je

en=Simplify[pom2/.{ϕ[t]-> ϕ0,ϕ'[t]-> 0}]

Potencial

U =Simplify[ pom2 - (1/2) m (R0^2) ((ϕ'[t])^2)]

dU=(1/R0)Simplify[D[U,ϕ[t]]]

Ravnovesni položaji so

slv ={ {ϕ[t]-> 0},{ϕ[t]-> π},{ϕ[t]->ArcCos[(g/(R0 (ω^2)))]}}

Stabilnost

ddU=(1/R0)D[dU,ϕ[t]]

ass = {g>0,m>0,R0>0,ω>0}

st=Simplify[FullSimplify[ddU/.slv,ass]]

Dobimo pogoja za stabilno ravnovesje

Simplify[Map[Reduce[# >0]&,st],ass]

Harmonična aproksimacija periode za primer g>R0 (ω^2)

perioda1 =Simplify[ 2π(Sqrt[m/ddU])/.slv[[1]],ass]

Harmonična aproksimacija periode za primer g<R0 (ω^2)

perioda2 =Simplify[ 2π(Sqrt[m/ddU])/.slv[[3]],ass]

Numerični izračun

Brezdimenzijski zapis newtonove enačbe je

eqeq = (λ- Cos[ϕ[t]]) Sin[ϕ[t]]+ ϕ''[t]

Tu je λ = (g/(R0 (ω^2))), t pa je sedaj brezdimezijski čas t ω

Izračun podan za začetni odmik

NumericnaResitev1[$λ_,ϕ0_,tmax_]:= Block[{slv},slv = NDSolve[{eqeq== 0,ϕ[0]== ϕ0,ϕ'[0]== 0}/.λ-> $λ,ϕ,{t,0,tmax}];
Plot[Evaluate[ϕ[t]/.slv],{t,0,tmax},PlotRange->{Automatic,{-π,π}}]]

NumericnaResitev1[0.1,π/3,10]

Manipulate[NumericnaResitev1[$λ,π/3,20],{$λ,0,4}]

Izračun podan za začetno brzino v spodnji legi

NumericnaResitev2[$λ_,v0_,tmax_]:= Block[{slv},slv = NDSolve[{eqeq== 0,ϕ[0]== 0,ϕ'[0]== v0}/.λ-> $λ,ϕ,{t,0,tmax}];
Plot[Evaluate[ϕ[t]/.slv],{t,0,tmax},PlotRange->{Automatic,{-2π,2π}}]]

NumericnaResitev2[0.3,1,10]

Manipulate[NumericnaResitev2[$λ,1,20],{$λ,0,4}]